home *** CD-ROM | disk | FTP | other *** search
/ Loadstar 47 / 047.d81 / weekly budget (.txt) < prev   
Commodore BASIC  |  2022-08-26  |  2KB  |  52 lines
  1. 10 poke53280,.:poke53281,.:print"[147][154]calculating...":goto50
  2. 20 a$(y)=a$(y)+right$(s$+str$(d%),6):return
  3. 30 for y=s to f:read d$:a$(y)=left$(d$+s$,10):a$(y)="[154]"+a$(y)+"[159]"
  4. 35 for x=0 to 4:read d%
  5. 40 a%(e,x)=a%(e,x)+d%:gosub 20:next:next:return
  6. 50 for x=1 to 30:s$=s$+" ":next:for x=1 to 40:l$=l$+"-":next:l$="[154]"+l$
  7. 100 w$="[147][159]           week1 week2 week3 week4 week5[154]"
  8. 110 i$="net income"+s$
  9. 120 data salary,300,300,300,300,300
  10. 130 data other,0,50,0,50,0
  11. 140 rem
  12. 200 id=2:e$="   expense"+s$
  13. 210 data church,35,40,35,40,35
  14. 220 data rent,0,0,0,575,0
  15. 230 data food,45,45,45,45,45
  16. 240 data phone,0,25,0,0,0
  17. 250 data lights,0,0,50,0,0
  18. 260 data water,20,0,0,0,0
  19. 270 data trash,8,0,0,0,0
  20. 280 data gasoline,10,10,10,10,10
  21. 290 data car loan,0,133,0,0,0
  22. 300 data car ins,0,31,0,0,0
  23. 310 data life ins,13,0,0,0,0
  24. 320 data bank card,25,0,0,0,0
  25. 330 data store card,10,0,0,0,0
  26. 340 data savings,10,10,10,10,10
  27. 350 rem
  28. 400 ed=14:d=id+ed+10:dim a$(d),a%(4,5):a$(0)=w$:a$(1)=i$:s=2:f=s+id-1:e=0
  29. 410 gosub 30:t=y:a$(y+4)=e$:s=y+5:f=s+ed-1:e=3
  30. 415 gosub 30:tt=y:a$(t)="[154] *forward [159]"
  31. 420 a$(t+1)=l$:a$(t+2)="[154] total in [159]":a$(t+3)=l$:a$(y)=l$
  32. 425 a$(y+1)="[154] total ex [159]"
  33. 430 a$(y+2)=l$:a$(y+3)="[154] *balance [159]"
  34. 435 for x=0 to 4:a%(2,x)=a%(0,x)+a%(1,x):y=t
  35. 440 d%=a%(1,x):gosub 20:y=t+2:d%=a%(2,x):gosub 20
  36. 445 a%(4,x)=a%(2,x)-a%(3,x):y=tt+1
  37. 450 d%=a%(3,x):gosub 20:y=tt+3:d%=a%(4,x):gosub 20:a%(1,x+1)=a%(4,x):next
  38. 460 for x=0 to d:print a$(x);:if x>22 goto 480
  39. 470 next:print:goto 500
  40. 480 get k$:if k$="" goto 480
  41. 490 goto470
  42. 500 print"[159]0[154])exit [159]1[154])redisplay [159]2[154])save [159]3[154])print[145]"
  43. 501 geta$:ifa$<"0"ora$>"3"then501
  44. 502 k=val(a$):ifk=.then60000
  45. 505 on k goto 460,510,520
  46. 510 save"budget",8:goto500
  47. 520 open 4,4:for x=0 to d:print#4,a$(x):next:close4:goto500
  48. 60000 open15,8,15,"r0:hello connect=hello connect":input#15,er:close15
  49. 60010 ifer<>63thenend
  50. 60020 print"[147][144]load"chr$(34)"hello connect"chr$(34)",8":print"run"
  51. 60030 poke631,13:poke632,13:poke198,2:end
  52.